(09 1) Schaubilder mit dem GWP darstellen (Ausdruck auch möglich)

Aus Augenbit

Darauf haben sicherlich alle GWP Nutzer schon lange gewartet. Wir können uns die Probleme vor die Finger führen. Wer über keinen GWP verfügt kann sich auch schon mal eine Funktion sichtbar machen, indem er den Plot ausdruckt und danach aufschäumt. Wie das geht erkläre ich später.

Der Befehl plot in einfacher Anwendung

Die Normalparabel

> plot(x^2,x=-4..4); Die bekannte Normalparabel. Zwei Angaben sind nötig: Plotterm und Plotbereich

Ein sehr karger plot Befehl; trotzdem kommt etwas raus

> plot(5);

Hier klappt es mit einer Angabe. Die 5 enthält keine Variable; Maple nimmt nun auf der x-Achse den Bereich -10 bis 10 (Standardeinstellung). Deshalb hat die x-Achse keine Beschriftung.

Wir werden anspruchsvoller

> plot(x^2,x=-3..3,y=-1..10);

Nun hat auch die y-Achse eine Beschriftung.

Bisherige Beobachtungen: plot (Term, x = a..b, y = c..d)

1. Maple setzt die x-Werte in den Term ein; das Ergebnis sind die y-Werte.

2. Besteht der Term nur aus einer reellen Zahl, ergibt sich logischerweise für alle x-Werte derselbe y-Wert; somit eine Parallele zur x-Achse.

Einfache Varianten bei plot

Kein Befehl von Maple hat wohl mehr Optionsmöglichkeiten

Farbe, Punkte statt Linien ...

Nun bestimmen wir mal die Farbe, den Stil und das Aussehen der Stilelemente. Die Namen kann man sich in den Menüpunkten ansehen. Die Farbnamen dummerweise nicht (dafür in der Hilfe). Farbplot können dann sinnvoll sein, wenn ein Tiger Drucker zur Verfügung steht, der Farben (gelb, rot, grün) durch verschiedene Erhebung darstellen kann. Sehr wichtig ist hingegen die Möglichkeit Linien auch verschieden gepunktet darzustellen. Ander Namenen für symbol sind: box,cross,circle,diamond. Scaling=constrained ist wichtig damit die Achsenscalierung beide gleich sind. Somit kann man sich besser die Lage der Funktion verdeutlichen.

> plot(x,x=-7..9,y=-8..10,color=blue,style=point,symbol=cross,scaling=constrained);


Linie anderer Art ....

> plot(-2*x+2,x=-5..7,y=-15..13,style=line,linestyle=4,thickness=2,color=magenta);

Varianten für linestyle: 1 (solid), 2 (dot), 3 (dash), 4 (dash-dot)

Beschriftungen: Überschrift und Achsen

> plot(x^2/4-2.5,x=-6..6,y=-3..7,color=black,scaling=constrained,title="Gedehnte Parabel",labels=["x-Achse","y-Achse"]);

Beschriftungen: Andere mögliche Formatierungen

> plot(x^2/4-2.5,x=-6..6,y=-3..7,color=black,scaling=constrained,title="Gedehnte Parabel",labels=["x-Achse","y-Achse"],titlefont=[COURIER,BOLD,16],labelfont=[HELVETICA,OBLIQUE,8],axesfont=[TIMES,BOLD,8]);

Maple ist sehr stur bei den Formatierungen für Titel, Achsen und Ziffern an den Achsen.

Im Prinzip ist folgende Syntax zwingend: ....font = [Schriftart, Schriftstil, Schriftgröße]

.... steht für label oder title oder axes (siehe oben)

Schriftart (TIMES, COURIER, HELVETICA,SYMBOL) und Schriftstil müssen groß geschrieben sein.

Die Schriftstile sind leider nicht einheitlich:

Bei TIMES sind möglich: ROMAN, BOLD, ITALIC, BOLDITALIC

Bei COURIER oder HELVETIC: nichts oder BOLD, OBLIQUE, BOLDOBLIQUE

Bei Schriftgröße: Zahl eingeben.

Anzahl der beschrifteten Punkte auf x- und y-Achse

> plot(x^2/8-3,x=-8..8,y=-4..7,tickmarks=[16,10]);

Du wirst bemerken, dass Maple nicht alle unsere Eingaben umsetzt. Welche, weiß ich auch nicht.

Mehrere Grafiken in einem Schaubild

Parabel und eine Gerade in einem Schaubild

Mehrere Objekte kann man in einer Menge oder in einer Liste zusammenfassen.

> plot([x^2/3-0.5,x/2+0.75], x=-5..8,y=-2..9,color=[black,blue]);

Wenn wir die Farben (die nun auch in einer Liste stehen müssen, falls jedes Objekt eine andere Farbe haben soll) nicht vorgeben, sucht sich Maple welche aus. Listen sind besser, da die Reihenfolge von Maple eingehalten wird; dies macht sich vor allem bei der Farbgestaltung bemerkbar.

Beispiel: Zwei Parabeln in einem Koordinatensystem

Parabel1: f_1(x)

> f_1:=x->2*x^2+5*x+4;

f_1 := x -> 2 *x^2 + 5 *x + 4

Parabel2: f_2(x)

> f_2:=x->3*x^2-2*x+8;

f_2 := x -> 3 *x^2 - 2 *x + 8

So nun hast du beide Parabeln je einer Funktion zugewiesen. Hier f_1(x) und f_2(x). [gesprochen f eins von x..]

Nun kommt der nächste Schritt. Du plottest beide Funktionen in ein Koordinatensystem.

> plot([f_1(x),f_2(x)], x=-10..10);

Du musst alle Parabeln in den eckigen Klammern aufzählen.

Um den Überblick zu wahren ist es wahrscheinlich vorteilhafter jeder parabel eine Funktionsvariabel zuzuordnen. Wenn du das nicht willst kannst du gleich alles in den Plotbefehl reinquetschen was das Ganze schwer lesbar macht.

> plot([3*x^2-2*x+8,2*x^2+5*x+4], x=-10..10);

Das Ganze ist natürlich mit Parabeln nach Lust und Laune erweiterbar.

Zeichnen "verwandter" Schaubilder

> plot([(x+3)^2,(x+2)^2,(x+1)^2,x^2,(x-1)^2,(x-2)^2],x=-5..6,y=-1..9);

Hat Maple nicht tolle Farben gewählt ? (Neue Wintermode) Die Tipparbeit von oben können wir uns doch sparen; es handelt sich um eine Folge von Schaubildern, bei denen jeweils eine Zahl verändert wurde: Dies kann man mit dem Term > (x-t)^2; ausdrücken; die Varibale t läuft von -3 bis 2. Also holen wir unser geeignetes Werkzeug aus dem Kasten: seq > plot([seq((x-t)^2,t=-3..2)],x=-5..6,y=-1..9);

Zwei völlig identische Grafiken. Ausblick: Später werden wir diese Schaubilder in einem Film angucken: Eine Parabel wandert.


Punkte und Strecken zeichnen

Punkte

> A:=[2,5];plot([A]);

Wo ist der Punkt ? Mit der rechten Maustaste erfährst Du, dass Maple nicht auf Punkte eingestellt ist. Korrigiere im Befehl. Der Punkt müsste erscheinen. Probieren wir es mit 2 Punkten: > B:=[-3,-5]:plot([A,B]);

Alles klar ? Defaulteinstellung von Maple ist: Verbindungsstrecken von Punkt zu Punkt zeichnen. Konsequenz: Style = point in den plot-Befehl > plot([A,B],style=point, symbol=cross,color=[green,blue]);

Mit den Farben scheint es nicht zu klappen.


Strecken (sind nun wohl klar)

> C:=[0,6]:plot([A,B,C,A],color=brown);

> De:=[4,-2]:plot([[De,C,A,De],[A,B,C]],color=blue);

Achte auf die Klammern: Die äußere eckige ist die Liste aller zu zeichnenden Objekte. Darin sind zwei Objekte enthalten, die jeweils von eckigen Klammern umschlossen sind. Jedes dieser beiden Objekte enthält Punkte, die eigentlich auch von eckigen Klammern umschlossen sind. Stelle dir vor, wir hätten alle diese [[[[ .... Übrigens: D können wir leider nicht verwenden. Maple hat den Buchstaben bereits belegt (später mehr). > Dreieck1:=[De,C,A,De];Dreieck2:=[A,B,C];

> plot([Dreieck1,Dreieck2]);So kann man die Klammern entwirren.

Parallelen zu den Koordinatenachsen

> plot([[[-6,-4],[-6,6]],[[1,-4],[8,-4]],5],color=[black,red,blue]);

Diese Klammern sind schon unübersichtlich. Arbeitet mit aussagekräftigen Variablen.

Dreiecke und Geraden zeichnen

Schlußgraphik

> plot([x^2,x,4,1], x=-5..6,y=-1..10,color=[red,black,blue],style=[line,point,point],symbol=[cross,diamond],linestyle=1,thickness=3);

> Zum Schuss noch wie du am besten einen Plot ausdruckst: Damit nur der Plot auf dem Ausdruck steht und nicht der Text muss eine Einsstellung in den Preferences (File/Preferences) vorgenommen werden. Dort mit den Pfeiltasten nach rechts auf die Registerkarte plotting gehen und mit TAB 'windows' auswählen und bestätigen. Nun wird der Plot auf einer neuen Seite dargestellt und lässt sich mit STRG+P auf eine Seite eingepasst ausdrucken. Mit STRG+F4 lässt sich das Fenster wieder schließen und du bist auf dem vorherigen WS.


Kopendium:

Media:09_1_GWP_Schaubilder_1.mws

Bei Verwendung von Firefox Worksheet.mws mit rechter Maustaste (Kontextmenütaste) herunterladen.


Beispiele